Dr.Quapp: Statistik für Mathematiker mit SPSS

Hinweise zur Übung 16 No 2

Zwei Spieler A und B werfen abwechselnd in festgelegter Reihenfolge ein Paar Würfel. A gewinnt, wenn er genau eine Summe von 6 Augen erhält, bevor B genau eine Summe von 7 Augen erhält.
a) Wie groß ist die Wahrscheinlichkeit, dass A gewinnt, wenn er das Spiel beginnt?
b) Wie groß ist die Wahrscheinlichkeit, dass A gewinnt, wenn B das Spiel beginnt?
Lösen Sie dies auch durch einen umfänglichen Test ($n>10 000$) in SPSS.

Die Wahrscheinlichkeit für eine Summe von 6 Augen ist $P_A =\frac{5}{36}$, diejenige für eine Summe von 7 Augen ist $P_B =\frac{6}{36}$. Sei $p$ die Wahrscheinlichkeit, dass A gewinnt, wenn er beginnt, und $r$ die Wahrscheinlichkeit, dass A gewinnt, wenn B beginnt.

Dann ist $p = P_A + (1- P_A) r$ , also die Wahrscheinlichkeit, dass es im 1.Versuch klappt + die Wahrscheinlichkeit, dass es im 1.Versuch nicht geklappt hat, wo ja dann B dran ist, der dann beginnt.

Andererseits ist $r = (1- P_B) p$ , denn A kann nur gewinnen, wenn B im 1.Versuch verliert, und dann natürlich wieder A dran ist. Ineinander einsetzen ergibt: $p = P_A + (1- P_A) (1- P_B) p$ , somit das Resultat
$p= \displaystyle\frac{P_A}{1 - (1- P_A) (1- P_B)}$ .

Mit obigen Werten ergibt sich $p= \displaystyle\frac{5/36}{(36\cdot 36- 31\cdot 30)/36^2 } =\displaystyle\frac{30}{61} =0.492$ ,
und $r= \displaystyle\frac{30}{36} \cdot \displaystyle\frac{30}{61} =0.41$ .

in SPSS kann man folgenderweise vorgehen:

/* Datei kreieren  */
/* Variable anzahl mit n=10000 Datens"atzen wird aktiviert  */
Input Program . 
LOOP #I=1 to 10000 . 
Compute anzahl=#I . 
FORMATS anzahl (F8).
END CASE . 
END LOOP . 
END FILE . 
END INPUT PROGRAM . 
EXECUTE . 

/* W"urfelergebnisse mit 4 W"urfeln */
DO Repeat 
a = x1 to x4.
COMPUTE a = RND(RV.UNIFORM(0.5,6.5)) .
End Repeat .

/* Summe der Augen von Spieler A */
compute yA=0.
Formats ya(F8).
EXECUTE .
Do Repeat 
a=x1 to x2.
Compute yA=yA+a.
End Repeat.
EXECUTE .

/* Summe der Augen von Spieler B */
compute yb=0.
Formats yb(F8).
EXECUTE .
Do Repeat 
a=x3 to x4.
Compute yB=yB+a.
End Repeat.
EXECUTE .

a) Nun interessiert die Wahrscheinlichkeit p, dass A beginnt und gewinnt. Dazu benutzen wir die Zählvariablen ga und gb, die jeweils den Sieg von A oder B registrieren.

Compute ga=0.
Compute gb=0.
If  (ya=6) ga=1.
Formats ga(F8).
If (ya<>6 & yb=7) gb=1.
Formats gb(F8).
EXECUTE .

DESCRIPTIVES
 VARIABLES=ga gb
 /STATISTICS=MEAN SUM .

Die gesuchte Wahrscheinlichkeit p ist dann $p= \frac{\sum ga }{ \sum ga + \sum gb }$ . Die Bestimmung von p braucht nur noch die kumulativen Summen:

CREATE
  /ga_1=CSUM(ga).
CREATE
  /gb_1=CSUM(gb).
compute  c=ga_1+gb_1.
FORMATS c (F8).
compute  p=0.
If c>0  p=ga_1/c.
EXECUTE .

b) Bestimmung der Wahrscheinlichkeit r, dass A gewinnt, wenn B beginnt.

Compute ga1=0.
Compute gb1=0.
If  (yb=7) gb1=1.
Formats gb1(F8).
 If (yb<>7 & ya=6) ga1=1.
Formats ga1(F8).
EXECUTE .
DESCRIPTIVES
  VARIABLES=ga1 gb1
  /STATISTICS=MEAN SUM .

/* r ist dann Sum(ga1)=/(sum(ga1)+sum(gb1)) */
/* Bestimmung von r in Feld c1 */ 
CREATE
  /ga1_1=CSUM(ga1).
CREATE
  /gb1_1=CSUM(gb1).
compute  c1=ga1_1+gb1_1.
FORMATS c1 (F8).
compute  r=0.
If c1>0  r=ga1_1/c1.
EXECUTE .

Mit

SORT CASES BY
  anzahl (D) .

kann man noch die gesamte Tabelle herumdrehen, um das Resultat in der 1.Zeile abzulesen, anstelle der 10000ensten.
Die theoretischen Werte können in Tests ab 10000 Würfen gut bestätigt werden.